Chapter 2 – Spheres Within Spheres (The Celestial Sphere – 3D Images)

The celestial sphere and coordinate positions
Celestial Sphere (3D images), reconstruct a 3D image via the Spectrum
Celestial Sphere (X-eyed 3D), 3D images via your ZX printer
Star Point, find out where a particular star or planet can be found in the sky
Star Tracker, plots a star or planet on a representation of the sky over a 24-hour period.

The Celestial Sphere – 3D Images

The celestial sphere, a device beloved by astronomers, is difficult to depict on a flat page so two separate attempts will be made to reconstruct a three-dimensional image via the Spectrum. Do not be too disappointed if the illusion does not work for you — it is only an experiment. I’ve tested both of these systems with reasonable success but some factors may be beyond your control.

The first system involves DRAWing two separate images on the TV screen and viewing the result through coloured filters. A colour TV must be used for the display and it may be necessary to adjust the contrast and colour controls for the best effect.

Figure 2.1 shows a COPY from the screen after RUNning this program. The COPY is obviously in monochrome and what it does not reveal is that the screen display uses two INK colours on a single overall PAPER colour.

The two overlapping images are PLOTted in separate INK colours The right hand image is in red (INK 2) and the left hand image in blue (INK 1). It will be noted that, with the exception of the east/west line and the letters E and W, both images are identical but displaced one from the other horizontally. The background colour is magenta (PAPER 3). These three colours have been chosen with considerable care and should not be amended until the experiment is completed as programmed.

Figure 2.1
This display appears in 3D, when viewed through red and blue filters on a colour TV The program introduces the necessary colour into the two images.


Viewing the results
You will need two deeply-coloured filters – one red and one blue – with which to view the TV display. It is important to stress that these should be deeply coloured. Pale tinted filters are useless in this application. In the test, the filter used should render its own coloured image on the TV screen virtually invisible, whilst the contrasting coloured image appears boldly: ie the blue filter should show up the red TV image and vice versa. The filters can be made of clear coloured cellophane or acetate sheet – in layers if need be to get the right depth of colour. A square 5 x 5cm is about the right size for each filter.

The screen results should be viewed from a distance of between four and eight feet (depending on the size of the TV screen) with the red filter held over the right eye and the blue filter over the left eye. The two separate coloured images should appear fused into one about midway between the TV and your eyes. A little patience may be necessary before the brain accepts the two discordantly coloured images as one.

The whole image, with the exception of the oval horizon line, the E/W line and the E and W markers, should appear on one plane. The horizon line and the E/W line should appear to project both towards and away from you with reference to this plane. Similarly, the letter W should appear close to you and the letter E further away. You will notice that the program title remains firmly fixed on the TV screen — this is because its colour is black (INK 0). Because black is in reality colourless, the filters have no effect on this portion of the display and so the 3D effect is absent.

The limitations
Despite the relative complexity of the screen COPY, the screen display has to be kept simple with as few as possible of the lines of the two coloured images intersecting.

This is because the Spectrum display will only support one INK colour per character square. When a second INK colour is overlaid, that portion of the design initially coloured red (INK 2) will be rendered blue (INK 1) if it falls in the same character square. This means that some parts of the design become visible with the wrong filter and the 3D image becomes fragmented.

To minimise this effect, the red image is PLOTted first: when viewed through the blue filter, this image plays a secondary role by only appearing faintly. The main image (in blue) appears boldly with as few spurious lines as possible from the red image to cause distraction. Despite the faintness of the red righthand image it is sufficiently effective when coupled with the blue lefthand image to give the illusion of 3D.

All colour TVs produce tints (colour plus white) and shades (colour plus black) from a blend of three colours — red, blue and green — via the three colour ‘guns’ in the TV tube. To ensure the maximum colour separation of the 3D images, only primary colours are used. The background colour should be passed by both colour filters equally to minimise eye strain. Hence the selection of colours (blue (INK 1) and red (INK 2) with a background colour of magenta — ie blue plus red — using PAPER 3).

The program
The program is quite straightforward and has sufficient REM statements for guidance — just enter, RUN it and view the results. The two coloured images are drawn between Lines 60 and 140, the variables a and al giving the necessary separation using the same FOR/NEXT f loop.

9 REM ***********************
10 REM 3D Celestial Sphere – TV
11 REM REM ***********************
30 PRINT “3D Celestial Sphere – use red & blue filters”
40 LET a=112: LET a1=160: LET b=80: LET c=79
50 REM ***********************
60 INK 2: REM Red LH image
70 REM ***********************
80 CIRCLE a1,b,c
90 PLOT a1-c,b: DRAW c*2,0
100 PLOT a1,b: DRAW -60,60: DRAW 120,-120
110 FOR f=0 TO PI*2 STEP .02
120 LET x=SIN f*c: LET y=COS f*c/3: PLOT a1+x,b+y: NEXT f
140 IF a=a1 THEN GO SUB 220: INK 0: PAPER 7: STOP
150 REM ***********************
160 INK 1: REM Blue LH image
170 REM ***********************
180 LET a1=a: GO TO 80
200 REM Blue E/W line+letters
220 PLOT a1,b: DRAW 10,28: DRAW -20,-56
230 PRINT AT 7,14;”E”;AT 16,12;”W”;AT 10,3;”N”;AT 10,15;”O”;AT 10,24;”S”
240 PRINT AT 4,5;”Np”;AT 19,21;”Sp”
250 REM ***********************
260 REM Red E/W line+letters
270 REM ***********************
280 INK 2: PLOT 160,b: DRAW -2,28: DRAW 10,-56
290 PRINT AT 7,18;”E”;AT 16,20;”W”;AT 10,9;”N”;AT 10,21;”O”;AT 10,30;”S”
300 PRINT AT 4,11;”Np”;AT 19,27;”Sp”
9900 REM ***********************
9990 SAVE “3D sphere”

Leave a Reply

Fill in your details below or click an icon to log in: Logo

You are commenting using your account. Log Out /  Change )

Google photo

You are commenting using your Google account. Log Out /  Change )

Twitter picture

You are commenting using your Twitter account. Log Out /  Change )

Facebook photo

You are commenting using your Facebook account. Log Out /  Change )

Connecting to %s