Chapter 7 – Star Systems (Tri-star Orbits)

Tri-star Orbits, places two companion stars in orbit around a central star
Binary-star Orbit, a more normal situation, one star orbiting another
Spirals, various options
Galaxy, simulate the Milky Way.

Our Sun is a pretty average and unexciting star as things go in the universe. The evolution and survival of life-forms on this planet have depended on its constant output of light and heat over hundreds of millions of years without solar fireworks. Also, the Sun is fairly small in star terms and this bodes well for its longevity. Larger stars have a habit of burning up their fuel supplies in double-quick time.

Astronomers have a scale called absolute magnitude by which to judge the true brightness of stars by assuming that they are all the same distance from Earth. This scale operates at a distance of 10 ‘parsecs’, ie about 33 light years away.

Our sun placed at this distance would only just be visible on a dark clear night to the unaided eye with an apparent magnitude of 4.7 (see the Stellar Magnitude program in Chapter 8 for an explanation of apparent magnitude). In contrast, the star Rigel in Orion would be magnitude – 7 at this distance, far out-shining even planet Venus at her best. At the opposite end of the scale, to show that our Sun is average, the nearest star to Earth (excluding the Sun) is Proxima Centauri, a red dwarf, and this would fade from its current brightness of 10.7 to about 15.0 at 10 parsecs.

Our Sun is also fairly conservative in not possessing a companion star to orbit around — it has a nice family of planets instead. The two are not mutually exclusive one would assume, but sharing the gravitational fields of two stars could play havoc with orbital distances and weather prospects of an inhabited planet. The following short programs enable double and triple stars to orbit each other — the sort of object that attracts the attention of astronomers rather than solitary magnitude 4.7 stars.

Tri-star Orbits

This is a modelling program to place two companion stars in orbit about a central star. The diameter of all three stars can be selected at will and each may be different. The orbit itself can also be tilted at any angle from 0° (edge-on viewpoint) to 90° (plan viewpoint). Particularly interesting orbital appearances occur with fairly large diameter stars (INPUT say 10 to 20) and a low inclination of orbit tilt (INPUT say 0 to 20). Here mutual eclipses of the stars are possible.

The program uses two FOR/NEXT loops, the f loop to compute the orbit and the n loop to CIRCLE the star’s image on the orbit. The n loop uses the OVER command so that each star is first drawn then deleted to give an impression of movement in orbit. Each star leaves a trail behind via the PLOT commands in Lines 130 and 140. The central star is only drawn once via Line 90 and remains fixed for the presentation.

The program
The basis of this program is yet another version of DRAWing ellipses. If the variable z is omitted from Line 120 (together with the / sign) then each orbit would be circular. It is this variable, via Lines 30 and 40, which compresses the circle into an ellipse according to the INPUT value for tilt. The maximum radius of the orbit is set by variable h to a value of 60. This is done to avoid the program crashing where an INPUT Of 90° for tilt and an INPUT of 20 for the diameter of orbiting stars 2 or 3 meant that the CIRCLE command would exceed the screen limit at top and bottom. Figures 7.1 and 7.2 illustrate typical orbits.

Figure 7.1
Two smaller stars orbit a massive central star.

Tri_Star_Orbit_30_20_2_10

Figure 7.2
Three stars of comparable diameter with orbits near edge-on.

Tri_Star_Orbit_10_20_14_16

Lagrangian orbits
The single orbit shared by two companion stars is relatively unstable. Minor perturbations (gravitational disturbances) will cause a neat system, with two objects diametrically opposed in the same orbit, to fail. One star will advance on the other with a fair chance of collision and annihilation or absorption of the lesser of the two stars.

Having said this, there are in fact two points on an orbit where a lesser star (or planet for that matter) is reasonably safe from such a catastrophe. These are called the Lagrangian points. Located some 60° ahead or behind the other orbiting body, each forms a perfect equilateral triangle with the central star. As the program stands, only one orbital position is calculated via Lines 110 and 120. The second star’s position is merely mirrored by Line 170 with the negative values. Amend the program thus to simulate two stars in Lagrangian orbits:

111 LET sx1=INT(SIN(f + 2)*h)
121 LET cy1=INT(COS(f + 2)*h/z)
140 PLOT x-sx1,y-cy1
170 CIRCLE x-sx1,y-cy1,d3

By adding a value of about 2 to f in Lines 111 and 121, the second body is advanced in its orbit so as to form an equilateral triangle between all three bodies. Obviously the orbit appears compressed for any orbit tilt less than 90° — the plan view.

It should be noted that beyond some asteroids associated with planet Jupiter and its orbit, we have no evidence of Lagrangian orbits for stars. It is reasonable to assume that if such star systems did exist, the orbit would be too large in relationship to the stars’ diameters to have any reasonable stability and to avoid tidal effects on the stars’ surfaces.

10 CLS : PRINT “Tri-star Orbits: “;
30 INPUT “Orbit tilt (0”; CHR$ 130; “to 90″; CHR$ 130;”)”;z
35 PRINT “tilt=”;z; CHR$ 130
40 LET z=1/SIN ((.1+z)/180*PI)
50 INPUT “Star 1 diameter (1-20): “;d1
60 INPUT “Star 2 diameter (1-20): “;d2
70 INPUT “Star 3 diameter (1-20): “;d3
80 LET x=128: LET y=88
90 LET h=60: CIRCLE x,y,d1
100 FOR f=0 TO PI*2 STEP .1
110 LET sx=INT (SIN f*h)
120 LET cy=INT (COS f*h/z)
130 PLOT x+sx,y+cy
140 PLOT x-sx,y-cy
150 OVER 1: FOR n=0 TO 1
160 CIRCLE x+sx,y+cy,d2
170 CIRCLE x-sx,y-cy,d3
180 NEXT n: OVER 0: NEXT f



Leave a Reply

Fill in your details below or click an icon to log in:

WordPress.com Logo

You are commenting using your WordPress.com account. Log Out /  Change )

Google photo

You are commenting using your Google account. Log Out /  Change )

Twitter picture

You are commenting using your Twitter account. Log Out /  Change )

Facebook photo

You are commenting using your Facebook account. Log Out /  Change )

Connecting to %s