Chapter 5 – Solar System Orbits (Solar Apex)

Orrery, simulates the scale and relative movement of the planets about the Sun
Bode’s Law
Kepler’s Orbits, demonstrates the first two of Kepler’s Laws
Orbit Foci, plotting the second focus
Comet Orbit, eccentric orbits
Halley’s Comet, depicts one complete orbit, 1948-2023
Pluto’s Orbit, plots the relative positions of Pluto and Neptune from 1880-2128, one complete orbit for Pluto
Solar Apex, corkscrew motion of a planet towards the Solar Apex.

Solar Apex

Even as you sit quietly at your Spectrum, you and, I hope, the whole room are moving rapidly across the universe. Nor are you moving constantly in a given direction but in a whole series of loops and whirling spirals. This series would read:

  1. Rotation about the Earth’s axis.
  2. Earth’s rotation about Earth/Moon axis.
  3. Earth’s rotation about the Sun.
  4. Sun’s rotation about the galaxy.
  5. Galaxy’s rotation about the Local Group of Galaxies (LG of G).
  6. LG of G rotation about the Virgo Super Cluster of Galaxies (VSCG).
  7. VSCG rotation about the universe.

Most astronomers and cosmologists theorise in this way, but categories 5 and 6 are pure speculation and category 7 improbable under currently accepted theories of the universe’s creation which conform to the idea of a Big Bang, where all groups of galaxies are still moving apart from the initial explosion. Of course if the universe is ‘closed’ and the galaxies finally come to rest they will probably reverse their motion back to the point of the Big Bang – in which case the galaxies are in orbit about this point even if their motion is in a straight line there and back (a maximum of one orbit only). A case of a shell falling back into the muzzle that fired it!

Down to Earth
The following program is a little less rarified and combines categories 3 and 4 to show the corkscrew motion of a planet towards a point in the sky, near the star Vega, called the Solar Apex. This is the direction in space in which the Sun is moving at a speed of 275 km/sec as it orbits our galaxy. The Sun is the straight line trace across the screen and the helical trace that of the planet, the orbit of which can be tilted at an angle for effect.

The various helices as PLOTted have a modest three-dimensional quality to them. Figure 5.13 is a typical example.

The two INPUT conditions control the orbit tilt, 1 for near edge-on, 10 for plan view whilst the planet INPUT alters the orbit radius. The period displayed is purely arbitrary and is controlled by the orbit radius merely to indicate that the helix will be finer and will occur in a shorter period of time on a smaller orbit.

Solar_Apex

5 BORDER 0: PAPER 0: INK 9
10 CLS : PRINT “Solar Apex”,
15 PRINT “tilt =”;
20 INPUT “1 to 10″,z: PRINT z
25 PRINT ,”planet=”;
30 INPUT “1 to 5″,d: PRINT d,”period=”;: LET d=d*10: LET x=100
40 FOR f=0 TO PI*9 STEP .1
45 PRINT AT 2,23;INT (d*f)
50 LET a=x-f*5+x: LET b=f*3+d
60 PLOT INK 6; OVER 1;a,b
70 PLOT INK 4;a+SIN f*d,b+COS f*d/z
80 NEXT f

***NB the keen-eyed among you will notice that the ‘Period’ label in the image is located in the wrong place. This is because the code for this in Line 30 should read: …PRINT d’,”period=”;… not as shown in the listing. This is my mistake not the author’s.


Chapter 5 – Solar System Orbits (Pluto’s Orbit)

Orrery, simulates the scale and relative movement of the planets about the Sun
Bode’s Law
Kepler’s Orbits, demonstrates the first two of Kepler’s Laws
Orbit Foci, plotting the second focus
Comet Orbit, eccentric orbits
Halley’s Comet, depicts one complete orbit, 1948-2023
Pluto’s Orbit, plots the relative positions of Pluto and Neptune from 1880-2128, one complete orbit for Pluto
Solar Apex, corkscrew motion of a planet towards the Solar Apex.

Pluto’s Orbit

On 21st January 1979, Pluto relinquished to Neptune the dubious honour of being the most remote planet from the Sun by crossing within Neptune’s orbit. Pluto will regain the ‘title’ in March 1999 by once more crossing Neptune’s orbit — this time in an outward direction.

A collision between the two planets is unlikely as Pluto’s orbit is inclined 17° to the general plane of the planets including Neptune. During this twenty-year period, Pluto will pass up to 10 AU (10 astronomical units = 10 x Earth to Sun distance) above Neptune’s orbit — a gap almost big enough to contain the complete orbit of the giant planet Jupiter. The planets Pluto and Neptune are themselves well separated — Neptune last overtook Pluto in the 1890s as each moved ponderously along its orbital track in periods of 165 years and 248 years respectively.

Screen display
The following program PLOTs to scale the relative positions of Pluto and Neptune from the year 1880 to 2128 — one complete orbit for Pluto. Both a plan and a section are displayed of the overlapping orbits, with a tiny flashing CIRCLE in the centre representing the Earth’s orbit (at the very centre of which is, of course, the Sun). The passing years are recorded in the top right of the screen and Pluto is PLOTted in a green pixel (a darker shade in monochrome) on a black background (PAPER 0: BORDER 0:) for clarity. The display PAUSEs briefly to PRINT six significant comments against specific dates relevant to the progress of the two planets.

Pluto’s elliptical orbit
Neptune’s orbit has the lowest eccentricity of all the planets, being a near-perfect circle. Because of this, its program requirements are minimal — just Line 340 both to calculate and PLOT its orbit, where variable f is used to increment the PLOT position.

In contrast, the bulk of the program from Line 110 is used to calculate Pluto’s elliptical orbit, which has the highest eccentricity of the major planets with a value of 0.25. Pluto moves faster when closest to the Sun (by wider spacing of the PLOT positions) but, because this presentation is to scale and overlaps Neptune’s orbit, it may not be obvious at this time.

Lines 300 and 310, both of which PLOT Pluto’s orbital progress, appear almost identical except for the expression at the end of Line 310:

“…y/200 + 10 ”

where /200 effectively compresses the y or vertical axis by a factor of 200 so that, instead of a second full ellipse being PLOTted, it is reduced to a near edge-on view of the orbit as shown in the lower part of the display.

Experiments with Pluto display
Once the program has been RUN a few times, using the screen COPY (Figure 5.12) to check that it works correctly, SAVE the program on tape. Now try changing some of the variables to see what effect it has. (These amendments will invariably corrupt an accurate presentation which is why the program should be SAVEd first.)

Figure 5.12
The orbits of Pluto and Neptune from two viewpoints.

Plutos_Orbit

The following variables can be tested for effect:
xx   x coordinate (horizontal) of the Sun
yy   y coordinate (vertical) of the Sun
f     position and increment steps to PLOT Neptune (Lines 110 and 340)
h    STEP value to main FOR/NEXT loop
t     FOR/NEXT main loop starting at value 0 (3 o’clock start)
w    relative eccentricity of Pluto’s orbit

The value 13 (Lines 300 and 310) and the value 55 (Line 340) control the radius of each planet’s orbit.

10 REM Pluto’s Orbit
20 LET t=0: BORDER 0: PAPER 0: INK 7: CLS : GO SUB 400
30 PRINT INK 5;”Pluto’s Orbit”
40 PRINT AT 11,0;”plan”;TAB 16;”Sun”;TAB 25; INK 5;”Pluto”
50 PRINT AT 15,14;”Neptune”
60 PRINT ”””edge-on”‘” view”
70 LET xx=140: LET yy=92
80 PLOT xx-55,0: DRAW 110,20,.1: DRAW -110,-20,.1
90 CIRCLE FLASH 1;xx,yy,2
100 CIRCLE FLASH 1;xx,10,2
110 LET f=12.3: LET w=28.7
120 LET h=.8: LET g=1e6
130 LET x=g/1000: LET y=0
140 LET i=h/4: LET v=0
150 LET r=x: LET s=y
160 LET x=x+i*v: LET y=y+i*w
170 GO SUB 260
180 LET x=r: LET y=s: LET o=h/2
190 LET v=v+o*b: LET w=w+o*c
200 GO SUB 300
210 FOR t=0 TO 155 STEP h
220 LET x=x+h*v: LET y=y+h*w
230 GO SUB 260
240 LET v=v+h*b: LET w=w+h*c
250 GO SUB 300: NEXT t: STOP
260 LET e=x*x+y*y: LET d=SQR e
270 LET a=-g/e: LET b=a*x/d
280 LET c=a*y/d: RETURN
300 PLOT INK 4;x/13+xx,y/13+yy
310 PLOT INK 4;x/13+xx,y/200+10
320 LET tt=1880+INT (t*1.6): PRINT AT 0,20;”year=”;tt
340 PLOT BRIGHT 1;xx+COS f*55,yy+SIN f*55: LET f=f+.05
360 IF tt=1888 OR tt=1929 OR tt=1979 OR tt=1999 OR tt=2040 OR tt=2127 THEN GO SUB 500
370 RETURN
410 LET b$=”1889 – Neptune ‘overtakes’ Pluto”
420 LET c$=”1930 – Pluto discovered”
430 LET d$=”Pluto inside Neptune’s orbit Jan 1979″
440 LET e$=”Pluto outside Neptune’s orbit Mar 1999″
450 LET f$=”Neptune completes orbit: 164 yrs”
460 LET g$=”Pluto completes orbit: 248 yrs”
470 DIM a$(40): RETURN
500 PRINT BRIGHT 1;AT 1,0;(b$ AND tt=1888)+(c$ AND tt=1929)+
(d$ AND tt=1979)+(e$ AND tt=1999)+(f$ AND tt=2040)+
(g$ AND tt=2127)
510 PAUSE 250: PRINT AT 1,0;a$: RETURN


Chapter 5 – Solar System Orbits (Halley’s Comet)

Orrery, simulates the scale and relative movement of the planets about the Sun
Bode’s Law
Kepler’s Orbits, demonstrates the first two of Kepler’s Laws
Orbit Foci, plotting the second focus
Comet Orbit, eccentric orbits
Halley’s Comet, depicts one complete orbit, 1948-2023
Pluto’s Orbit, plots the relative positions of Pluto and Neptune from 1880-2128, one complete orbit for Pluto
Solar Apex, corkscrew motion of a planet towards the Solar Apex.

Halley’s Comet

Halley’s Comet is without doubt the most famous comet of all time and, as a visit to our part of the solar system is due shortly, a program would not be inappropriate.

1066 and all that
Edmund Halley (1656 – 1742) did not discover this comet but was the first to notice that the bright comets seen in 1531,1607 and 1682 had practically identical orbital data and were one and the same object reappearing in the skies about every 75 years.

Halley’s Comet can now be traced back to 611 BC, via Chinese records, but perhaps the most famous reference of all in European history is its depiction in the Bayeux Tapestry of 1066 with the inscription of INTIMIRANT STELLA. Every return of the Comet since King Harold’s reign has been recorded and this is most unusual as the longevity of comets is measured in hundreds rather than thousands of years. This indicates that Halley’s Comet is a substantial body able to survive repeated visits to the inner solar system and the relatively great heat radiated upon it from the Sun.

You should be asking the question: How do comets survive repeated crossings of all the planets without collison? Well, comets (or rather, the survivors after over 5000 million years) have learned to avoid the orbital plane which all planets occupy with highly-inclined orbits. The comet crosses this danger zone for only a few days each perihelion passage.

The program
The program depicts one complete orbit of Halley’s Comet beginning in 1948 _ the year the Comet started its current journey towards both Earth and Sun from beyond the orbit of Neptune. The Comet will return to this aphelion position again in about 2023. The perihelion passage occurs on 10th February 1986 and the program PAUSEs briefly at this point. (See Figure 5.11.) During mid-November 1985 the comet is a binocular object below the Pleiades.

This program is a variation of the Comet Orbit program, but uses one specific orbit produced by the line LET w = 4.5. Again, only one half of the orbit is computed and PLOTted — the inward journey — but each x and y coordinate position is entered into two arrays, x(t) and y(t). These are then used in a second FOR/NEXT loop to PLOT the Comet’s journey back into deep space.

It is necessary to add PAUSE 10 to this second FOR/NEXT loop to slow the PLOTting down to the same speed as the first loop. This indicates the rapidity with which the Spectrum can PLOT pixel positions once the actual position has been computed and SAVEd in an array. Try pressing any key to cancel the PAUSE statement to see what happens.

Screen display
At the top of the screen is denoted the current year against the Comet’s progress — the Comet itself is PLOTted in a different coloured pixel for the inward and outward journeys (for clarity) using inverse graphics on a black screen (BORDER 0: PAPER 0: INK 9).

Figure 5.11
The path of Halley’s comet over a 75-period. Closest approach to the Sun occurs in February 1986.

Halleys_Comet

10 REM Halley’s Comet
20 BORDER 0: PAPER 0: INK 7: CLS : PAPER 5: INK 9
30 PRINT ” Halley’s Comet year= “; FLASH 1;” ”
40 PAPER 1
50 PRINT AT 11,1;”Sun”
60 PLOT 40,80: GO SUB 390
70 PAPER 5
80 LET w=4.5
90 DIM x(170): DIM y(170)
100 LET h=.212: LET g=1e6
110 LET x=g/1e3: LET y=0
120 LET i=h/4: LET v=0
130 LET r=x: LET s=y: LET z=0
140 LET x=x+i*v: LET y=y+i*w
150 GO SUB 230
160 FOR t=1 TO 170
170 LET yr=1948+INT (t/4.5)
180 PRINT AT 0,26;yr
190 LET x=x+h*v: LET y=y+h*w
200 GO SUB 230
210 LET v=v+h*b: LET w=w+h*c
220 GO SUB 260: NEXT t: STOP
230 LET e=x*x+y*y: LET d=SQR e
240 LET a=-g/e: LET b=a*x/d
250 LET c=a*y/d: RETURN
260 PLOT INK 4;40+x/5,y/5+80
270 LET x(t)=x/5: LET y(t)=y/5
280 IF y<0 THEN GO TO 300
290 RETURN
300 PLOT OVER 1;40+x/5,y/5+80
310 PRINT #0; FLASH 1;” Comet at perihelion passage ”
320 PAUSE 300: INPUT “”
330 FOR t=169 TO 1 STEP -1
340 LET yr=2023+INT (-t/4.5)
350 PRINT AT 0,26;yr
360 PLOT INK 6;40+x(t),-y(t)+80
370 PAUSE 10: NEXT t: STOP
390 CIRCLE 40,80,8
400 CIRCLE 40,80,40
410 FOR n=1 TO 3: READ a,b: PLOT 40+a,20: DRAW 0,120,b: NEXT n
420 PRINT AT 13,1;”Earth”
430 PRINT AT 18,1;”Jupiter Saturn Uranus Neptune”: RETURN
440 DATA 40,2,105,1.1,160,.9


Chapter 5 – Solar System Orbits (Comet Orbit)

Orrery, simulates the scale and relative movement of the planets about the Sun
Bode’s Law
Kepler’s Orbits, demonstrates the first two of Kepler’s Laws
Orbit Foci, plotting the second focus
Comet Orbit, eccentric orbits
Halley’s Comet, depicts one complete orbit, 1948-2023
Pluto’s Orbit, plots the relative positions of Pluto and Neptune from 1880-2128, one complete orbit for Pluto
Solar Apex, corkscrew motion of a planet towards the Solar Apex.

Comet Orbit

This program is the second variation of Kepler’s Orbits. This time we’re dealing with highly eccentric orbits which can usually be ascribed to comets and meteor streams. It is generally recognised that regular meteor displays (shooting stars in the Earth’s atmosphere), like the Perseids in August of each year, are the debris from comets, strewn along each comet’s orbit.

The program allows INPUT values from 0.5 (a highly eccentric orbit, essentially of two parallel lines) to 17 (a full oval) filling the Spectrum screen (see Figure 5.10). To avoid the erroneous if interesting effects of calculating the cometary position close to the Sun, only half the orbit is PLOTted. The lower half of the orbit is a mirror image of the upper portion — Lines 200 and 210 coping with their respective halves. The program STOPs when y becomes negative (once the half orbit is computed).

Figure 5.10
Two extremes of cometary orbit in plan view from full oval to highly eccentric as sample INPUTS.

Comet_Orbit_15

Comet_Orbit_0-5

The program demonstrates very effectively Kepler’s 2nd law of Orbital/ Planetary Motion (see the Kepler’s Orbits program) in the way in which a comet spends most of its time moving very slowly whilst remote from the Sun and only bursts into activity at perihelion passage, as it is called.

10 PRINT “Comet Orbit “;
30 INPUT “Value (.5 to 17): “;w
35 PRINT w’ PAPER 5;”Perihelion
Aphelion”
40 PRINT AT 11,0;”Sun”: CIRCLE 40,83,1
50 LET h=.2: LET g=1e6
60 LET x=g/1e3: LET y=0
70 LET i=h/4: LET v=0
80 LET r=x: LET s=y: LET z=0
90 LET x=x+i*v: LET y=y+i*w
100 GO SUB 160
110 FOR t=0 TO 300
120 LET x=x+h*v: LET y=y+h*w
130 GO SUB 160
140 LET v=v+h*b: LET w=w+h*c
150 GO SUB 190: NEXT t: STOP
160 LET e=x*x+y*y: LET d=SQR e
170 LET a=-g/e: LET b=a*x/d
180 LET c=a*y/d: RETURN
190 IF y<0 THEN STOP
200 PLOT 40+x/5,y/5+83
210 PLOT 40+x/5,-y/5+83
220 RETURN


Chapter 5 – Solar System Orbits (Orbit Foci)

Orrery, simulates the scale and relative movement of the planets about the Sun
Bode’s Law
Kepler’s Orbits, demonstrates the first two of Kepler’s Laws
Orbit Foci, plotting the second focus
Comet Orbit, eccentric orbits
Halley’s Comet, depicts one complete orbit, 1948-2023
Pluto’s Orbit, plots the relative positions of Pluto and Neptune from 1880-2128, one complete orbit for Pluto
Solar Apex, corkscrew motion of a planet towards the Solar Apex.

Orbit Foci

In the previous program, Kepler’s Orbits, reference is made to the Sun being at one focus of an elliptical orbit. Where is the second or ’empty’ focus as it is called?

Quite simply it is at an equal distance measured from the Sun to the perihelion position (the nearest point in orbit to the Sun) but transferred to the aphelion position (remotest point in orbit to the Sun). If you have already keyed in the Kepler’s Orbits program, then the minor modifications from Line 300 in this program are all that is necessary before RUN-ning the revision. This version will PLOT the second focus position once a half-orbit is PLOTted and the position of perihelion is known. Figure 5.9 demonstrates.

Figure 5.9
The program plots the second, or empty, focus (f2) of any selected elliptical orbit. The Sun is at the first focus (f1).

Orbit_Foci

This program is quite important in demonstrating that the Spectrum, via the program, is PLOTting a true elliptical orbit. There is a simple test to check results. RUN the program and measure, either on the video screen or a paper COPY if you have access to the ZX printer, the total distance around a triangle formed between any point on the orbit and the two foci. No matter what point you choose on a given orbit the total distance will be the same.

You are following the same procedure, in reverse, as the gardener who insists on making perfect oval (ie elliptical) flower beds in a lawn. He uses two stakes (representing the two foci) and a loop of string about them drawn taut (representing your triangle) to trace out the shape. Quite obviously the total length of the string remains constant, as should your measurements.

10 PRINT “Orbits Foci “;
30 INPUT “Velocity (13 to 30): “;w
40 PRINT w;AT 10,15;”f1″: CIRCLE 128,85,2
50 LET h=.4: LET g=1000000
60 LET x=g/1000: LET y=0
70 LET i=h/4: LET v=0
80 LET r=x: LET s=y: LET z=0
90 LET x=x+i*v: LET y=y+i*w
100 GO SUB 200
110 LET x=r: LET y=s: LET o=h/2
120 LET v=v+o*b: LET w=w+o*c
130 GO SUB 300
140 FOR t=0 TO w*7 STEP h
150 LET x=x+h*v: LET y=y+h*w
160 GO SUB 200
170 LET v=v+h*b: LET w=w+h*c
180 GO SUB 300: NEXT t: STOP
200 LET e=x*x+y*y: LET d=SQR e
220 LET a=-g/e: LET b=a*x/d
240 LET c=a*y/d: RETURN
300 PLOT x/10+128,y/10+85
310 IF x=-50 AND x>z THEN PLOT 228+x/10,85: PRINT AT 10,(228+x/10)/8-1;”f2”
320 LET z=x
330 RETURN


Chapter 5 – Solar System Orbits (Kepler’s Law)

Orrery, simulates the scale and relative movement of the planets about the Sun
Bode’s Law
Kepler’s Orbits, demonstrates the first two of Kepler’s Laws
Orbit Foci, plotting the second focus
Comet Orbit, eccentric orbits
Halley’s Comet, depicts one complete orbit, 1948-2023
Pluto’s Orbit, plots the relative positions of Pluto and Neptune from 1880-2128, one complete orbit for Pluto
Solar Apex, corkscrew motion of a planet towards the Solar Apex

Kepler’s Orbits

Johannes Kepler, between 1609 and 1618, found that planets, and in fact all orbiting bodies, follow three laws of planetary motion:

  1. The orbit of the planet is an ellipse with the Sun at one focus of that ellipse.
  2. The planet moves in its orbit at such velocity that its radius vector (the angle as seen from the Sun to any point on the orbit) sweeps out an equal area in a similar time interval — see Figures 5.4 and 5.5.
  3. The orbital period squared is proportional to the mean (average) distance from the Sun cubed.

The following program demonstrates the first two of Kepler’s Laws of Planetary Motion by PLOTting elliptical orbits with the spacing between the individual PLOT positions at equal time intervals. The PLOTted pixel (representing the orbiting planet) is seen to ‘accelerate’ as it passes close to the Sun (the small CIRCLE in the centre of the screen) particularly as the orbits become more elliptical (higher eccentricity) against the values INPUT for initial velocity.

These INPUT values are purely arbitrary. Effectively, the higher the value the more circular the orbit, the lower the value (Figure 5.6) the more eccentric the orbit and the closer the planet passes to the Sun. The first position PLOTted marks the point of ‘aphelion’, ie the most remote part of the orbit from the Sun. The point of the orbit closest to the Sun is called ‘perihelion’.

Figure 5.4: Kepler’s 1st and 2nd Laws of Planetary Motion
A planet PE (shown in a highly elliptical orbit for clarity) sweeps out an equal area (shaded) in an equal time interval — its velocity constantly changing according to its current distance from the Sun.

Kepler_1

Figure 5.5: Kepler’s 3rd Law of Planetary Motion
Each planet sweeps out an area (shaded) in an equal time interval proportional to the orbit radius. In this simplified solar system with the orbits equally spaced, P1 covers a complete quadrant whilst P2 covers 0.35 of a quadrant (1/√23) and P3 covers 0.19 of a quadrant (1/√33).

Keplar_3_Law

If an INPUT of >12 is ENTERed then odd things start happening with the PLOTted results. These have nothing to do with Kepler’s Laws — but with short-comings of the program. They have, however, been deliberately left in to demonstrate three effects that can happen to a body in orbit about, or passing close to, a more massive planet.

An INPUT of 12 will cause rotation of the whole orbit so that the aphelion position (and also the perihelion position although this is not obvious) moves in a clockwise direction. This effect mimics the orbit rotation of any planet but even in the case of Mercury, the planet closest to the Sun and with the highest velocity of all the planets, it is only detectable over hundreds of complete orbits. (See Figure 5.7)

Figure 5.6
Lower INPUT values produce more elliptical orbits.

Kepler_Orbit_15

Figure 5.7
Rotation of orbit.

Kepler_Orbit_12

An INPUT of 10 will cause the capture of the body into a smaller and faster orbit. It is believed that many comets have been captured into smaller orbits by passing sufficiently close to the massive planet Jupiter and, to a lesser extent, Saturn. This obviously assumes a third body which our program does not contain but it remains of interest to demonstrate an effect. (See Figure 5.8)

Figure 5.8
Capture of larger orbit into a smaller orbit.

Kepler_Orbit_10

An INPUT of 7 or less will cause the planet to pass so close to the Sun that the planet is ejected out of the solar system in what is called a sling-shot manoeuvre. In reality no planet would be subjected to this indignity — if such a thing ever occurred it would have been billions of years ago — there is no place for rebel planets today. However space scientists use this effect to send spacecraft from one planet to the next in a game of planetary billiards, poaching a little of the host planet’s gravitational field to accelerate the craft to high velocities impossible to achieve by rocket power from Earth.

An explanation
Why does this program produce these effects? Quite simply because the program does not calculate with sufficient accuracy the position of the planet when close to the Sun. The minutest error is added to the next computation producing the effects displayed. The situation is not assisted by the fact that, at the point of perihelion, the vertical or y coordinates as PLOTted pass from positive to negative values. All in all, a case of using a potential disadvantage to good effect, even if not good mathematics!

Amending the program
Once the program has been RUN a few times, try amending (one at a time) some of the variables. The most important variable to change is h, which controls the STEP intervals in the FOR/NEXT loops to RUN the program. If it is made smaller then the orbit will be PLOTted with greater accuracy, particularly at perihelion position. However it will now PLOT incredibly slowly whilst the planet is near aphelion. You change the value — you take your choice.

This particular program is used a number of times elsewhere in this book — usually with modifications to suit particular purposes.

10 PRINT “Kepler’s Orbits : “;
30 INPUT “Velocity (5 to 30): “;w
40 PRINT w: CIRCLE 128,85,2
50 LET h=.5: LET g=1000000
60 LET x=g/1000: LET y=0
70 LET i=h/4: LET v=0
80 LET r=x: LET s=y
90 LET x=x+i*v: LET y=y+i*w
100 GO SUB 200
110 LET x=r: LET y=s: LET o=h/2
120 LET v=v+o*b: LET w=w+o*c
130 GO SUB 300
140 FOR t=0 TO 400 STEP h
150 LET x=x+h*v: LET y=y+h*w
160 GO SUB 200
170 LET v=v+h*b: LET w=w+h*c
180 GO SUB 300: NEXT t: STOP
200 LET e=x*x+y*y: LET d=SQR e
220 LET a=-g/e: LET b=a*x/d
240 LET c=a*y/d: RETURN
300 PLOT x/10+128,y/10+85
305 PRINT AT 20,0;”x=”;x'”y=”;y
310 RETURN


Chapter 5 – Solar System Orbits (Bode’s Law)

Orrery, simulates the scale and relative movement of the planets about the Sun
Bode’s Law
Kepler’s Orbits, demonstrates the first two of Kepler’s Laws
Orbit Foci, plotting the second focus
Comet Orbit, eccentric orbits
Halley’s Comet, depicts one complete orbit, 1948-2023
Pluto’s Orbit, plots the relative positions of Pluto and Neptune from 1880-2128, one complete orbit for Pluto
Solar Apex, corkscrew motion of a planet towards the Solar Apex.

Bode’s Law

In 1772, the German astronomer Johann Bode demonstrated that a simple mathematical progression — eg 0 + 4, 3 + 4, 6 + 4, 12 + 4,… — could explain the average distance of successive planets from the Sun — where Earth had a value of 10 (6 + 4). At the time, only six planets were known to exist, not surprisingly, they fitted reasonably well with what came to be known as ‘Bode’s Law’.

The discovery of Uranus beyond Saturn in 1781 and the minor planet Ceres, between Mars and Jupiter, in 1801 confirmed the Law by falling nicely into place. However, the discovery of Neptune in 1846 and Pluto in 1930 did not uphold the Law — Pluto occupying the orbit allocated by Bode for Neptune as the following short program demonstrates. Perhaps you can improve on Bode to provide a better explanation?

The program
The upper half of the screen LISTs and DRAWs semi-orbital arcs calculated from the variable ‘bode’ (z + 4); the lower half the actual values as READ from DATA. The display is scaled to maximum size for the DRAW routine where PI = semi-circle, and the program stops with an error message (integer out of range) in attempting to DRAW the final arc for Pluto according to Bode’s Law. Thus Neptune’s actual orbit, in the lower display, fits the space between Uranus and Neptune as allocated by Bode and shown in the upper display. Study of the numerical values displayed confirms this as Figure 5.3 shows.

Figure 5.3

Bodes_Law

Note: This program, in demonstrating Bode’s Law, refers to average distances from the Sun. Most planetary orbits are not neat circles but slightly elliptical — highly so in Pluto’s case causing it to overlap Neptune’s orbit. The program Pluto’s Orbit, later in this chapter, fully explains this situation.

10 REM Titius-Bode’s Law
20 LET x=185: LET y=88
30 LET z=0: DIM a$(32*11)
40 PRINT PAPER 6;a$; PAPER 1;a$: FLASH 1
50 PRINT AT 0,1;”Titius-Bode’s Law”
60 PRINT AT 11,1;”Actual dist”
70 FLASH 0: PAPER 6: INK 9
80 FOR n=1 TO 10
90 LET bode=z+4
100 READ p$,a
110 PRINT AT n,0;p$;TAB 8;bode
120 PRINT AT n+11,0; PAPER 1;p$;TAB 8;a
130 PLOT x-a/6,y
140 DRAW a/3,0,PI
150 PLOT x-z/6,y
160 DRAW z/3,0,-PI
170 LET z=z+z
180 IF n=1 THEN LET z=3
190 NEXT n
200 DATA “Mercury”,3.9,”Venus”,7.2,”Earth”,10,”Mars”,15.2,”Ceres”,
26.5,”Jupiter”,52,”Saturn”,95.4,”Uranus”,192,”Neptune”,301,”Pluto”,
395